M5StickCでできること〜M5StickCでGROVE-温湿度・気圧センサを使う

M5StickC用の環境設定が完了したので、次に、「GROVE – 温湿度・気圧センサ（BME280）」をつないでみます。

リンク

スケッチは、M5Stackのもの（記事はこちら）とほとんど同じです。

#include <M5StickC.h>
#include "Seeed_BME280.h"
#include <Wire.h>

BME280 bme280;

void setup(){
  M5.begin();
  M5.Lcd.setRotation(3);
  if(!bme280.init()){
    while(true);
  }
}

void loop() {
  uint32_t pres = bme280.getPressure();
  M5.Lcd.setCursor(0, 0, 2);
  M5.Lcd.printf("Temp:%5.1fC\n", bme280.getTemperature());
  M5.Lcd.printf("Humi:%5d%%\n", bme280.getHumidity());
  M5.Lcd.printf("Pres:%5dhPa\n", pres/100 );
  M5.Lcd.printf("Alti:%5.1fm\n", bme280.calcAltitude(pres));
  delay(1000);
}

温度、湿度、気圧、高度が表示されました。

次に、上記センサで測定した温度データを、Wi-Fi通信でクラウドに送信します。
このスケッチも、M5Stackのもの（記事はこちら）とほとんど同じです。

#include <M5StickC.h>
#include "Seeed_BME280.h"
#include <Wire.h>
#include <WiFi.h>

const char* ssid     = "xxxxxxxx";
const char* password = "xxxxxxxx";
char host[40]        = "xxxxxxxx";
char event[40]       = "/temp_receive.php";

BME280 bme280;

void setup(){
  M5.begin();
  M5.Lcd.setRotation(3);
  M5.Lcd.setCursor(0, 0, 2);

  if(!bme280.init()){
    while(true);
  }

  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    M5.Lcd.print(".");
  }
  M5.Lcd.print("\r\nWiFi connected\r\nIP address: ");
  M5.Lcd.println(WiFi.localIP());
  delay(2000);
}

void loop() {
  float temp = bme280.getTemperature();

  M5.Lcd.setCursor(0, 0, 2);
  M5.Lcd.printf("Temp:%5.1fC\n", temp);

  WiFiClient client;
  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    M5.Lcd.println("connection failed");
    return;
  }

  String url = String(event) + "?val0=" + String(int(temp*1024/100));
  M5.Lcd.print("Requesting URL:");
  M5.Lcd.println(url);

  client.print(String("GET ") + url + " HTTP/1.1\r\n" + "Host: " + host + "\r\n" + "Connection: close\r\n\r\n");
  unsigned long timeout = millis();
  while (client.available() == 0) {
    if (millis() - timeout > 5000) {
      M5.Lcd.println(">>> Client Timeout !");
      client.stop();
      return;
    }
  }
  while(client.available()){
    String line = client.readStringUntil('\r');
  }
  delay(30000);
}

データは正しく送信されました。